I have to get some buffers via com port, and then to separate numbers from
letters in that "string" (variant). What is the most "elegant" way to do it?
There should be (maybe) an array of strings and second array of numbers or
something like that, just to have control over numbers and letters.

Maybe something like this:

dim strNumStr as string, strAlfStr as string
dim i as integer

(Assumes data is in strData)

for i = 1 to len(strData)
  select case asc(mid$(strData,i,1))
     case 48 to 57    '0 - 9
        strNumStr = strNumStr & mid$(strData,i,1)
     case else           'Everything else.
        strAlfStr = strAlfStr & mid$(strData,i,1)
  end select
next i

msgbox strNumStr & "   " & strAlfStr

If you want to include the period as part of the numerical input,
just change the case like this:

     case 46, 48 to 57    ' .  , 0 - 9

Regards
Saga

Show quoteHide quote

Show quote Hide quote yep, thanx.
But, I wondered if there is some simple expression that doesn't need any
loops or something that will do the job quicker. Anyway, your code "snippet"
is better than mine ;).

Are they separated with spaces? Can you give input example? You may find the
Split function useful:

Dim s() As String
Dim i As Long

s = Split(sInput, " ")
For i = LBound(s) To UBound(s)
    Debug.Print "'"; s;"'"
Next



Show quoteHide quote

Beware of Val() function. It ignores white spaces as the help file suggest:

Debug.Print Val("501 8th ST")

Prints:

5018

Also, my last code fragment had a typo, try:

Private Sub Form_Load()
    Dim s() As String
    Dim i As Long

    s = Split("123 abc  def", " ")
    For i = LBound(s) To UBound(s)
        Debug.Print "'"; s(i); "'"
    Next

End Sub

It prints:

'123'
'abc'
''
'def'

There are 2 spaces between "abc" and "def".



Show quoteHide quote

Just as a point of information, the LBound for an array created by
the Split function is always 0 (no matter what the Option Base
setting is).

Rick

What about the isNumeric function?

On 19 Oct 2005 17:28:04 -0700, "ClubKnowledge"
<w***@clubknowledge.com> wrote:

IsNumeric tends to decide that a lot of things are numbers, when we
would not expect them to be numbers.

First off, I got the impression that the OP is trying to separate
numbers that are imbedded within a larger text string containing
non-digits; so unless you were suggesting examining each character
in the text string (for which IsNumeric would be acceptable), I
would suggest not using IsNumeric...

From a previous post of mine...

I usually try and steer people away from using IsNumeric to
"proof" supposedly numeric text. Consider this (also see note at
end of post):

    ReturnValue = IsNumeric("($1,23,,3.4,,,5,,E67$)")

Most people would not expect THAT to return True. IsNumeric has
some "flaws" in what it considers a proper number and what most
programmers are looking for.

I had a short tip published by Pinnacle Publishing in their Visual
Basic Developer magazine that covered some of these flaws.
Originally, the tip was free to view but is now viewable only by
subscribers.. Basically, it said that IsNumeric returned True for
things like -- currency symbols being located in front or in back
of the number as shown in my example (also applies to plus, minus
and blanks too); numbers surrounded by parentheses as shown in my
example (some people use these to mark negative numbers); numbers
containing any number of commas before a decimal point as shown in
my example; numbers in scientific notation (a number followed by
an upper or lower case "D" or "E", followed by a number equal to
or less than 305 -- the maximum power of 10 in VB); and
Octal/Hexadecimal numbers (&H for Hexadecimal, &O or just & in
front of the number for Octal).

NOTE:
======
In the above example and in the referenced tip, I refer to $ signs
and commas and dots -- these were meant to refer to your currency,
thousands separator and decimal point symbols as defined in your
local settings -- substitute your local regional symbols for these
if appropriate.

As for your question about checking numbers, here are two
functions that I have posted in the past for similar
questions..... one is for digits only and the other is for
"regular" numbers:

     Function IsDigitsOnly(Value As String) As Boolean
         IsDigitsOnly = Len(Value) > 0 And _
                        Not Value Like "*[!0-9]*"
     End Function

     Function IsNumber(ByVal Value As String) As Boolean
         '   Leave the next statement out if you don't
         '   want to provide for plus/minus signs
         If Value Like "[+-]*" Then Value = Mid$(Value, 2)
         IsNumber = Not Value Like "*[!0-9.]*" And _
                           Not Value Like "*.*.*" And _
                           Len(Value) > 0 And Value <> "." And _
                           Value <> vbNullString
     End Function

Here are revisions to the above functions that deal with the local
settings for decimal points (and thousand's separators) that are
different than used in the US (this code works in the US too, of
course).

     Function IsNumber(ByVal Value As String) As Boolean
       Dim DP As String
       '   Get local setting for decimal point
       DP = Format$(0, ".")
       '   Leave the next statement out if you don't
       '   want to provide for plus/minus signs
       If Value Like "[+-]*" Then Value = Mid$(Value, 2)
       IsNumber = Not Value Like "*[!0-9" & DP & "]*" And _
                  Not Value Like "*" & DP & "*" & DP & "*" And _
                  Len(Value) > 0 And Value <> DP And _
                  Value <> vbNullString
     End Function

I'm not as concerned by the rejection of entries that include one
or more thousand's separators, but we can handle this if we don't
insist on the thousand's separator being located in the correct
positions (in other words, we'll allow the user to include them
for their own purposes... we'll just tolerate their presence).

     Function IsNumber(ByVal Value As String) As Boolean
       Dim DP As String
       Dim TS As String
       '   Get local setting for decimal point
       DP = Format$(0, ".")
       '   Get local setting for thousand's separator
       '   and eliminate them. Remove the next two lines
       '   if you don't want your users being able to
       '   type in the thousands separator at all.
       TS = Mid$(Format$(1000, "#,###"), 2, 1)
       Value = Replace$(Value, TS, "")
       '   Leave the next statement out if you don't
       '   want to provide for plus/minus signs
       If Value Like "[+-]*" Then Value = Mid$(Value, 2)
       IsNumber = Not Value Like "*[!0-9" & DP & "]*" And _
                  Not Value Like "*" & DP & "*" & DP & "*" And _
                  Len(Value) > 0 And Value <> DP And _
                  Value <> vbNullString
     End Function

Rick

Shrink Wrap
Iterative GetObject
get list of file names in a directory
Is any device connected to COM1 port
Division by Zero Error - Help Urgent
InStr search counter
Merge array in VB
Odd sequencin of window display
How to write a PDF file from Visual Basic ?
task bar?