Hi all ,

   I am using visual basic 6 . Am using Shell() to execute external
program in VB .

   How to stop\Kill the exe program in code ? Any sample code available ?

Thanks.

On Fri, 03 Jun 2005 11:56:41 +0800, weetat <t***@wavex-tech.com>
wrote:

You need to get the hWnd of the Shelled application

A Google on groups for: Shell reparent "J French"
will come up with most of the code
- including a bit you don't yet want

InstanceToWnd is the core bit

Then to shut down the spawned App send it a WM_CLOSE message

Finding the hWnd is a bit tricky for some Apps, if they use splash
screens or spawn other bits.

Try....

Safely Shut Down a Running Application
http://www.thescarms.com/vbasic/StopProcess.asp

I tried it, but I can't stop a program with it unless it was started with
the same VB app.
Is this how it is meant to be?

RBS

Show quoteHide quote

Well... you did say....

So, which app do you want to kill? Your app? or the Shelled app?

OK, so this is meant for stopping an application that you started first with
Start Process.

RBS

Show quoteHide quote

There must be something here you can use....

Process Related
http://www.thescarms.com/vbasic/VBProcessRelated.asp

Thanks, will have a look at that.
For my purpose something like this is good enough:

Function CloseApp(ByVal strApp As String, _
                  ByVal strClass As String) As Long

    Dim hwnd As Long

    On Error GoTo ERROROUT

    hwnd = FindWindowHwndLike(0, _
                              strClass, _
                              strApp, _
                              0)

    If hwnd = 0 Then
        CloseApp = 0
        Exit Function
    End If

    'Post a message to the window to close itself
    '--------------------------------------------
    PostMessage hwnd, WM_CLOSE, 0&, 0&

    CloseApp = hwnd

    Exit Function
ERROROUT:

    On Error GoTo 0
    CloseApp = 0

End Function


Function FindWindowHwndLike(ByVal hWndStart As Long, _
                        ByVal ClassName As String, _
                        ByVal WindowTitle As String, _
                        ByVal level As Long) As Long

    'finds the first window where the class name start with ClassName
    'and where the Window title starts with WindowTitle, returns Hwnd
    '-----------------------------------------------------------------
    Dim hwnd As Long
    Dim sWindowTitle As String
    Dim sClassName As String
    Dim R As Long

    'Initialize if necessary. This is only executed
    'when level = 0 and hWndStart = 0, normally
    'only on the first call to the routine.
    If level = 0 Then
        If hWndStart = 0 Then
            hWndStart = GetDesktopWindow()
        End If
    End If

    'Increase recursion counter
    level = level + 1

    'Get first child window
    hwnd = GetWindow(hWndStart, GW_CHILD)

    Do Until hwnd = 0

        'Search children by recursion
        Call FindWindowHwndLike(hwnd, ClassName, WindowTitle, level)

        'Get the window text
        sWindowTitle = Space$(255)
        R = GetWindowText(hwnd, sWindowTitle, 255)
        sWindowTitle = Left$(sWindowTitle, R)

        'get the class name
        sClassName = Space$(255)
        R = GetClassName(hwnd, sClassName, 255)
        sClassName = Left$(sClassName, R)

        'Check if the window matches the search parameters
        If (sWindowTitle Like WindowTitle & "*") And _
           (sClassName Like ClassName & "*") Then
            FindWindowHwndLike = hwnd
            Exit Function
        End If

        'Get next child window
        hwnd = GetWindow(hwnd, GW_HWNDNEXT)

    Loop

End Function


RBS


Show quoteHide quote

ByVal vs ByRef
Check Digits
Privileges and killing a process
How do you code Asynchronous MP3 playing with VB6/API?
Monitoring a software installation.....
Slow WMI Select Query
VB6 and SPLIT
Forum for VB6?
Tabulating document proerties from a folder in Access
Sorting a 2d array by more than 1 column