Is there a way to set a global option to tell IsNumeric() to not match
to scientific notation?  In other words, treat any alpha characters as
non-numeric characters.

I suspect the majority of code that uses IsNumeric() does not expect
the allowance for scientific notation, and my personal experience is
that any code I have had to maintain actually behaves badly when
an accidental match to scientific notation by IsNumeric() is
encountered.

  - Larry

No, you'd have to check for d,D,e or E in the string.  It also allows $ and
other symbols so while it's a decent first check it's only a start in
validating a numeric entry.

Bob Butler wrote:
Is there any comprehensive MSDN documentation on VB6 IsNumeric() ?
That "other symbols" matching is something I didn't know about.
There's probably some positional logic in play for those.

  - Larry

Yes indeed, there is.  If, for example, you use a single-character string,
IsNumeric only returns true for values between "0" to "9".


Rob

The best way to think of IsNumeric() is as an "IsConvertable" test, rather than
as an input string parser. The rule is pretty simple:

    If CDbl(txt) won't throw an error, then IsNumeric(txt) will return True.

It is useful in routines that are reading text files for data, and situations
like that, where a test prior to conversion is helpful.

Scientific notation is not the only problem you can have with IsNumeric.
Looks like it is time to ressurrect my old IsNumeric posting. From a
previous posting of mine...

I usually try and steer people away from using IsNumeric to "proof"
supposedly numeric text. Consider this (also see note below):

    ReturnValue = IsNumeric("($1,23,,3.4,,,5,,E67$)")

Most people would not expect THAT to return True. IsNumeric has some "flaws"
in what it considers a proper number and what most programmers are looking
for.

I had a short tip published by Pinnacle Publishing in their Visual Basic
Developer magazine that covered some of these flaws. Originally, the tip was
free to view but is now viewable only by subscribers.. Basically, it said
that IsNumeric returned True for things like -- currency symbols being
located in front or in back of the number as shown in my example (also
applies to plus, minus and blanks too); numbers surrounded by parentheses as
shown in my example (some people use these to mark negative numbers);
numbers containing any number of commas before a decimal point as shown in
my example; numbers in scientific notation (a number followed by an upper or
lower case "D" or "E", followed by a number equal to or less than 305 -- the
maximum power of 10 in VB); and Octal/Hexadecimal numbers (&H for
Hexadecimal, &O or just & in front of the number for Octal).

NOTE:
======
In the above example and in the referenced tip, I refer to $ signs and
commas and dots -- these were meant to refer to your currency, thousands
separator and decimal point symbols as defined in your local settings -- 
substitute your local regional symbols for these if appropriate.

As for your question about checking numbers, here are two functions that I
have posted in the past for similar questions..... one is for digits only
and the other is for "regular" numbers:

     Function IsDigitsOnly(Value As String) As Boolean
         IsDigitsOnly = Len(Value) > 0 And _
                        Not Value Like "*[!0-9]*"
     End Function

     Function IsNumber(ByVal Value As String) As Boolean
         '   Leave the next statement out if you don't
         '   want to provide for plus/minus signs
         If Value Like "[+-]*" Then Value = Mid$(Value, 2)
         IsNumber = Not Value Like "*[!0-9.]*" And _
                           Not Value Like "*.*.*" And _
                           Len(Value) > 0 And Value <> "." And _
                           Value <> vbNullString
     End Function

Here are revisions to the above functions that deal with the local settings
for decimal points (and thousand's separators) that are different than used
in the US (this code works in the US too, of course).

     Function IsNumber(ByVal Value As String) As Boolean
       Dim DP As String
       '   Get local setting for decimal point
       DP = Format$(0, ".")
       '   Leave the next statement out if you don't
       '   want to provide for plus/minus signs
       If Value Like "[+-]*" Then Value = Mid$(Value, 2)
       IsNumber = Not Value Like "*[!0-9" & DP & "]*" And _
                  Not Value Like "*" & DP & "*" & DP & "*" And _
                  Len(Value) > 0 And Value <> DP And _
                  Value <> vbNullString
     End Function

I'm not as concerned by the rejection of entries that include one or more
thousand's separators, but we can handle this if we don't insist on the
thousand's separator being located in the correct positions (in other words,
we'll allow the user to include them for their own purposes... we'll just
tolerate their presence).

     Function IsNumber(ByVal Value As String) As Boolean
       Dim DP As String
       Dim TS As String
       '   Get local setting for decimal point
       DP = Format$(0, ".")
       '   Get local setting for thousand's separator
       '   and eliminate them. Remove the next two lines
       '   if you don't want your users being able to
       '   type in the thousands separator at all.
       TS = Mid$(Format$(1000, "#,###"), 2, 1)
       Value = Replace$(Value, TS, "")
       '   Leave the next statement out if you don't
       '   want to provide for plus/minus signs
       If Value Like "[+-]*" Then Value = Mid$(Value, 2)
       IsNumber = Not Value Like "*[!0-9" & DP & "]*" And _
                  Not Value Like "*" & DP & "*" & DP & "*" And _
                  Len(Value) > 0 And Value <> DP And _
                  Value <> vbNullString
     End Function

Rick

How can I trim off leading zeros from a number? Help greatly appreciated!!!
need to register richtx32.ocx in Vista
randomize encryption ..
Decimal to Longs
Ftp file overwrite warning
SQL Update question
Nice
opening files and applications, same as if one did it by hand
Am I delusional or is it VB?
Cannot creating Excel objects in Windows Vista